# $Id$
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>

pkgname=bluez4
pkgver=4.101
pkgrel=1
pkgdesc="Deprecated daemon and tools for the Bluetooth protocol stack"
url="http://www.bluez.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus' 'python2')
conflicts=('bluez')
replaces=("bluez<=$pkgver")
makedepends=('gstreamer0.10-base' 'libusb-compat' 'libsndfile' 'libusbx')
optdepends=("gstreamer0.10-base: bluetooth GStreamer support"
            "alsa-lib: Audio bluetooth devices support"
            "dbus-python: to run bluez-simple-agent"
            "pygobject: to run bluez-simple-agent"
            "libusb-compat: USB adapters support"
            "cups: CUPS backend")
options=('!libtool')
backup=(etc/bluetooth/{main,rfcomm,audio,network,input,serial}.conf
        etc/dbus-1/system.d/bluetooth.conf)
source=("http://www.kernel.org/pub/linux/bluetooth/bluez-${pkgver}.tar.bz2"
        '0001.patch'
        '0002.patch'
        '0003.patch'
        '0004.patch')

build() {
  cd bluez-"${pkgver}"

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --libexecdir=/usr/lib \
    --sbindir=/usr/lib/bluetooth \
    --enable-gstreamer \
    --enable-alsa \
    --enable-usb \
    --enable-dfutool \
    --enable-dund \
    --enable-hidd \
    --enable-pand \
    --enable-gatt \
    --enable-cups \
    --enable-wiimote \
    --disable-test \
    --with-systemdunitdir=/usr/lib/systemd/system

  patch -p1 -i ../0001.patch
  patch -p1 -i ../0002.patch
  patch -p1 -i ../0003.patch
  patch -p1 -i ../0004.patch

  make
}

package() {
  cd bluez-"${pkgver}"
  make DESTDIR=${pkgdir} install

  # adjust systemd service file
  sed -i 's#/usr/sbin/#/usr/lib/bluetooth/#' \
    "${pkgdir}"/usr/lib/systemd/system/bluetooth.service

  install -d ${pkgdir}/etc/bluetooth
  install -m644 network/network.conf \
                input/input.conf \
                audio/audio.conf \
                serial/serial.conf \
    ${pkgdir}/etc/bluetooth/
  
  # FS#27630
  install -Dm755 test/simple-agent "${pkgdir}"/usr/bin/bluez-simple-agent
  install -Dm755 test/test-device "${pkgdir}"/usr/bin/bluez-test-device
  install -Dm755 test/test-input "${pkgdir}"/usr/bin/bluez-test-input
  sed -i 's#/usr/bin/python#/usr/bin/python2#' \
    "${pkgdir}"/usr/bin/bluez-simple-agent \
    "${pkgdir}"/usr/bin/bluez-test-device \
    "${pkgdir}"/usr/bin/bluez-test-input

  # drop files that are in bluez-libs
  rm -rf "${pkgdir}"/usr/{include,lib/pkgconfig}
  rm "${pkgdir}"/usr/lib/libbluetooth*

  # drop files that are in bluez-utils
  rm -rf "${pkgdir}"/lib
  rm "${pkgdir}"/usr/bin/{ciptool,hcitool,l2ping,rfcomm,sdptool}
  rm "${pkgdir}"/usr/share/man/man1/{ciptool,hcitool,rfcomm,sdptool}.1
  rm "${pkgdir}"/usr/lib/bluetooth/{hciattach,hciconfig}
  rm "${pkgdir}"/usr/share/man/man8/{hciattach,hciconfig}.8
}
md5sums=('902b390af95c6c5d6d1a17d94c8344ab')