# $Id: PKGBUILD 92254 2013-06-03 11:15:27Z allan $
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Florian Pritz <bluewind@xinu.at>
# Contributor: Paulo Matias <matiasΘarchlinux-br·org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Sebastian Schwarz <seschwar@gmail.com>

pkgbase=oss
pkgname=(oss libflashsupport-oss)
pkgver=4.2_2008
pkgrel=1
arch=(i686 x86_64)
url="http://developer.opensound.com/"
license=(GPL2)
makedepends=(gtk2)
source=("http://www.4front-tech.com/developer/sources/stable/gpl/oss-v${pkgver/_*}-build${pkgver/*_}-src-gpl.tar.bz2"
        'linux-3.8.0.patch::http://www.opensound.com/forum/download/file.php?id=113'
        'linux-3.10.0.patch::http://www.opensound.com/forum/download/file.php?id=126'
        'linux-3.10.7.patch::http://www.opensound.com/forum/download/file.php?id=129'
        oss.service
        remove-hal.patch
        rm-init-scripts.patch
        soundon.patch)
md5sums=('cc5c982a3d9da51ff612285db61b4952'
         'effecefb774f1d08ef9f0af0ad205c34'
         'c7fc0fa5c739eda9d265bb9a4f69ecd9'
         '1860b69bea048109cec8d49cc2696586'
         '39c46b10a6bc56fc146d669a61bd3028'
         'cd7f1dc6166bba8c94d96f3a28e948a5'
         'b9a380a0ac8896390d71ac13676f27e1'
         '65f07fe241bfbf912f76d8b6d8f276b5')
_dir=oss-v${pkgver/_*}-build${pkgver/*_}-src-gpl

prepare() {
    cd "$srcdir/$_dir"

    # OSS wants an empty build directory
    rm -rf build
    mkdir build

    # make OSS compile with current Linux kernels
    patch -p0 < "$srcdir/linux-3.8.0.patch"
    patch -p0 < "$srcdir/linux-3.10.0.patch"
    patch -p0 < "$srcdir/linux-3.10.7.patch"

    # remove outdated stuff
    cd setup/Linux
    patch -p2 < "$srcdir/rm-init-scripts.patch"
    rm oss/etc/S89oss
    patch -p2 < "$srcdir/remove-hal.patch"
    rm oss/scripts/*oss_usb-create-device*
    patch -p1 < "$srcdir/soundon.patch"
    cd ../..
}

build() {
    cd "$srcdir/$_dir/build"
    ../configure --enable-libsalsa=NO --regparm
    make build
    gcc $CFLAGS -shared -fPIC -Wall -Werror oss/lib/flashsupport.c \
            -o prototype/usr/lib/oss/lib/libflashsupport.so
}

package_oss() {
    pkgdesc="Open Sound System UNIX audio architecture"
    depends=(gcc make linux-headers libtool sed)
    optdepends=('gtk2: for graphical mixer (ossxmix)'
                'libflashsupport-oss: Adobe flash plugin support')
    conflicts=(oss-linux oss-linux-free oss-testing)
    backup=(usr/lib/oss/soundon.user)
    install=oss.install

    cd "$srcdir/$_dir/build"
    install -Dm755 prototype/usr/lib/oss/lib/libflashsupport.so \
            "$pkgdir/usr/lib/oss/lib/libflashsupport.so"
    make DESTDIR="$pkgdir/" copy
    cd "$pkgdir"

    # usr-move fixes
    mv usr/sbin/* usr/bin
    rmdir usr/sbin
    grep -IlrZ '\<s\?bin\>' . \
            | xargs -0 sed -i 's,\<\(usr/\)\?s\?bin\>,usr/bin,g' --
    grep -IlrZ '\<lib/modules\>' . \
            | xargs -0 sed -i 's,\<\(usr/\)\?lib/modules\>,usr/&,g' --

    chmod -R a+rX .  # FS#13815
    install -Dm644 "$srcdir/oss.service" usr/lib/systemd/system/oss.service
}

package_libflashsupport-oss() {
    pkgdesc="Adobe flash plugin support lib (OSSv4)"
    conflicts=(libflashsupport libflashsupport-pulse)
    depends=(oss)

    install -dm755 "$pkgdir/usr/lib"
    ln -s oss/lib/libflashsupport.so "$pkgdir/usr/lib/libflashsupport.so"
}