# $Id: PKGBUILD 179599 2013-03-07 17:46:37Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=cmake
pkgver=2.8.10.2
pkgrel=5
pkgdesc="A cross-platform open-source make system"
arch=('i686' 'x86_64')
url="http://www.cmake.org/"
license=('custom')
depends=('curl' 'libarchive' 'shared-mime-info')
makedepends=('qt4' 'emacs')
optdepends=('qt5-base: cmake-gui')
install="${pkgname}.install"
source=("http://www.cmake.org/files/v2.8/${pkgname}-${pkgver}.tar.gz"
        'qt4.patch'
        'qt5.patch'
        'qt5-2.patch')
md5sums=('097278785da7182ec0aea8769d06860c'
         '4933fbe934d3989923f0a60a78dac44e'
         'f9cf09184771013d6727ef5842eddbc4'
         'aa103b9ee50d6befd6e4f5cee8df1069')

build() {
  cd ${pkgname}-${pkgver}

  # qmake refers to Qt5
  patch -p1 -i "${srcdir}"/qt4.patch
  patch -p1 -i "${srcdir}"/qt5.patch
  patch -p1 -i "${srcdir}"/qt5-2.patch

  # Qt is built with reduce-relocations
  export CFLAGS="${CFLAGS} -fPIC -I/usr/include/qt5"
  export CXXFLAGS="${CXXFLAGS} -fPIC -I/usr/include/qt5"

  ./bootstrap --prefix=/usr \
    --mandir=/share/man \
    --docdir=/share/doc/cmake \
    --system-libs \
    --qt-gui \
    --qt-qmake=/usr/bin/qmake
    # --parallel=$(/usr/bin/getconf _NPROCESSORS_ONLN)
  make -j4
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  vimpath="${pkgdir}/usr/share/vim/vimfiles"
  install -Dm644 Docs/cmake-indent.vim "${vimpath}"/indent/cmake-indent.vim
  install -Dm644 Docs/cmake-syntax.vim "${vimpath}"/syntax/cmake-syntax.vim

  install -Dm644 Docs/cmake-mode.el \
    "${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el
  emacs -batch -f batch-byte-compile "${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el

  install -Dm644 Copyright.txt \
    "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}