# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Kristoffer Fossgård <kfs1@online.no>
# Contributor: Greg Bouzakis <gregbouzakis@gmail.com>
pkgname=terminus-font
pkgver=4.38
pkgrel=1
pkgdesc="Fixed width bitmap font"
arch=('any')
url="http://terminus-font.sourceforge.net"
license=('GPL2' 'custom:OFL')
depends=('fontconfig' 'xorg-fonts-encodings' 'xorg-mkfontscale' 'xorg-mkfontdir')
replaces=('xserver-terminus-fonts')
install=terminus-font.install
source=(http://downloads.sourceforge.net/terminus-font/$pkgname-$pkgver.tar.gz)
md5sums=('a8e792fe6e84c86ed2b6ed3e2a12ba66')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  chmod +x configure
  ./configure \
    --prefix=/usr \
    --psfdir=/usr/share/kbd/consolefonts \
    --x11dir=/usr/share/fonts/misc
    
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  install -d $pkgdir/etc/fonts/conf.avail
  install -D -m 644 75-yes-terminus.conf $pkgdir/etc/fonts/conf.avail/

  install -D -m 644 OFL.TXT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et: