# $Id$
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Gary van der Merwe <garyvdm@gmail.com>

pkgbase=dbus-python
pkgname=('python-dbus' 'python2-dbus' 'python-dbus-common')
pkgver=1.0.0
pkgrel=1
pkgdesc="Python bindings for DBUS"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL')
url="http://www.freedesktop.org/wiki/Software/DBusBindings"
makedepends=('pkg-config' 'docutils' 'dbus-glib' 'python' 'python2')
options=('!libtool')
source=(http://dbus.freedesktop.org/releases/${pkgbase}/${pkgbase}-${pkgver}.tar.gz)
md5sums=('775a8235736bf760cdd96e2d76546469')

build() {
  cp "${srcdir}/${pkgbase}-${pkgver}" "${srcdir}/${pkgbase}-${pkgver}-python2" -r

  cd "${srcdir}/${pkgbase}-${pkgver}"  
  ./configure --prefix=/usr
  make

  cd "${srcdir}/${pkgbase}-${pkgver}-python2"  
  PYTHON=python2 ./configure --prefix=/usr
  make
}


package_python-dbus() {
  depends=('dbus-glib' 'python' 'python-dbus-common')

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  # Remove files that will be in common.
  rm -rf ${pkgdir}/usr/{share,include}
  rm -rf ${pkgdir}/usr/lib/pkgconfig
}

package_python2-dbus() {
  depends=('dbus-glib' 'python2' 'python-dbus-common')
  replaces=('dbus-python')
  conflicts=('dbus-python')
  provides=('dbus-python')

  cd "${srcdir}/${pkgbase}-${pkgver}-python2"
  make DESTDIR="${pkgdir}" install

  # Move files that will be in common to a dir that package_python-dbus-common
  # will use.
  rm -rf "${srcdir}/${pkgbase}-${pkgver}-common"
  mkdir -p "${srcdir}/${pkgbase}-${pkgver}-common/usr/lib"
  mv ${pkgdir}/usr/{share,include} "${srcdir}/${pkgbase}-${pkgver}-common/usr/"
  mv ${pkgdir}/usr/lib/pkgconfig "${srcdir}/${pkgbase}-${pkgver}-common/usr/lib/"
}

package_python-dbus-common() {
  cp -r ${srcdir}/${pkgbase}-${pkgver}-common/* ${pkgdir}
}