# Maintainer: Brad Fanella <bradfanella@archlinux.us>
# Contributor: Daenyth <Daenyth+Arch [at] gmail [dot] com>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: ice-man <icemanf@gmail.com>
# Contributor: Techlive Zheng <techlivezheng [at] gmail [dot] com>

_pkgbase=aircrack-ng
pkgname=(aircrack-ng airdrop-ng airgraph-ng)
pkgver=1.1
pkgrel=7.1
arch=('i686' 'x86_64')
url="http://www.aircrack-ng.org"
license=('GPLv2')
source=("http://download.aircrack-ng.org/${pkgname}-${pkgver}.tar.gz")


build() {
    cd ${srcdir}/${_pkgbase}-${pkgver}
    make SQLITE=true unstable=true
}

package_aircrack-ng() {
  pkgdesc="A key cracker for the 802.11 WEP and WPA-PSK protocols"
  depends=('openssl' 'sqlite3' 'iw' 'net-tools')
  install=aircrack-ng.install

  cd ${srcdir}/${_pkgbase}-${pkgver}
  make DESTDIR=${pkgdir} SQLITE=true unstable=true \
      bindir=/usr/bin sbindir=/usr/sbin mandir=/usr/share/man/man1 install
}

package_airdrop-ng() {
  pkgdesc="Arule based deauth tool on aircrack-ng"
  depends=('python2' 'pylorcon' 'lorcon-old-svn')
  conflicts=('aircrack-ng-scripts')

  cd ${srcdir}/${_pkgbase}-${pkgver}/scripts/airdrop-ng

  sed -i "s/python/python2/g" airdrop-ng.py

  install -Dm755 airdrop-ng.py               ${pkgdir}/usr/bin/airdrop-ng

  # airdrop-ng doc
  install -Dm644 README                      ${pkgdir}/usr/share/doc/airdrop-ng/README
  install -Dm644 docs/Apple.sample.txt       ${pkgdir}/usr/share/doc/airdrop-ng/Apple.sample.txt
  install -Dm644 docs/dropRules.conf.example ${pkgdir}/usr/share/doc/airdrop-ng/dropRules.conf.example

  # airdrop-ng libs
  install -Dm644 lib/colorize.py             ${pkgdir}/usr/lib/airdrop-ng/colorize.py
  install -Dm644 lib/libOuiParse.py          ${pkgdir}/usr/lib/airdrop-ng/libOuiParse.py
  install -Dm644 lib/libDumpParse.py         ${pkgdir}/usr/lib/airdrop-ng/libDumpParse.py

  # airdrop-ng man page
  install -Dm644 docs/airdrop-ng.1           ${pkgdir}/usr/share/man/man1/airdrop-ng.1
}

package_airgraph-ng() {
  pkgdesc="Graphing tool for the aircrack-ng suite"
  depends=('python2' 'graphviz')
  conflicts=('aircrack-ng-scripts')

  cd ${srcdir}/${_pkgbase}-${pkgver}/scripts/airgraph-ng

  sed -i "s/python/python2/g" dump-join.py
  sed -i "s/python/python2/g" airgraph-ng.py

  sed -i "s:/usr/local/bin/lib:/usr/lib/airgraph-ng:g" airgraph-ng.py

  # dump-join.py (airgraph-ng)
  install -Dm755 dump-join.py           ${pkgdir}/usr/bin/dump-join

  # dump-join.py (airgraph-ng) man page
  install -Dm644 man/dump-join.1        ${pkgdir}/usr/share/man/man1/dump-join.1

  # airgraph-ng bin
  install -Dm755 airgraph-ng.py         ${pkgdir}/usr/bin/airgraph-ng

  # airgraph-ng doc
  install -Dm644 README                 ${pkgdir}/usr/share/doc/airgraph-ng/README

  # airgraph-ng libs
  install -Dm644 lib/lib_Airgraphviz.py ${pkgdir}/usr/lib/airgraph-ng/lib_Airgraphviz.py

  # airgraph-ng man page
  install -Dm644 man/airgraph-ng.1      ${pkgdir}/usr/share/man/man1/airgraph-ng.1
}

md5sums=('f7a24ed8fad122c4187d06bfd6f998b4')