# $Id: PKGBUILD 127534 2011-06-16 08:21:30Z juergen $
# Contributor: John Proctor <jproctor@prium.net>
# Contributor: Daniel White <daniel@whitehouse.id.au>
# Maintainer: Juergen Hoetzel <juergen@archlinux.org>
# Contributor: Leslie Polzer (skypher) 

pkgname=sbcl
pkgver=1.0.49
pkgrel=1
pkgdesc="Steel Bank Common Lisp"
arch=('i686' 'x86_64')
license=('custom')
depends=('glibc')
provides=('common-lisp' 'cl-asdf')
makedepends=('sbcl' 'texinfo')
source=("http://downloads.sourceforge.net/project/sbcl/sbcl/$pkgver/$pkgname-$pkgver-source.tar.bz2" "arch-fixes.lisp")
md5sums=('8d15c6af6388fcd9efbd13f301b7ba33'
         '7ac0c1936547f4278198b8bf7725204d')
url="http://www.sbcl.org/"
install=sbcl.install

build() {
  unset SBCL_HOME
  cd ${srcdir}/${pkgname}-${pkgver}
  # Make a multi-threaded SBCL, disable LARGEFILE  
  cat >customize-target-features.lisp <<EOF
(lambda (features)
  (flet ((enable (x) (pushnew x features))
         (disable (x) (setf features (remove x features))))
  (enable :sb-thread)
  (disable :largefile)))
EOF

  sh make.sh --prefix=${pkgdir}/usr
  mkdir -p ${pkgdir}/usr
  pushd doc/manual
  make info || return 1
  popd 
  INSTALL_ROOT=${pkgdir}/usr sh install.sh

  src/runtime/sbcl --core output/sbcl.core --script ${srcdir}/arch-fixes.lisp
  mv sbcl-new.core ${pkgdir}/usr/lib/sbcl/sbcl.core

# sources
  mkdir -p ${pkgdir}/usr/share/sbcl-source
  cp -R -t ${pkgdir}/usr/share/sbcl-source \
    ${srcdir}/${pkgname}-${pkgver}/{src,contrib}

# drop unwanted files
  find ${pkgdir}/usr/share/sbcl-source -type f \
    -name \*.fasl -or \
    -name \*.o -or \
    -name \*.log -or \
    -name \*.so -or \
    -name a.out -delete

  rm ${pkgdir}/usr/share/sbcl-source/src/runtime/sbcl
  rm ${pkgdir}/usr/share/sbcl-source/src/runtime/sbcl.nm

  find ${pkgdir} \( -name Makefile -o -name .cvsignore \) -delete

  rm ${pkgdir}/usr/share/info/dir
  gzip -9nf ${pkgdir}/usr/share/info/*

  # license
  install -D -m644 ${srcdir}/${pkgname}-${pkgver}/COPYING \
                   ${pkgdir}/usr/share/licenses/${pkgname}/license.txt
}