# $Id: PKGBUILD 70241 2010-02-25 17:21:11Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgbase=gnome-desktop-sharp
pkgname=('gnome-desktop-sharp' 'libgnome-desktop-sharp' 'gnome-panel-sharp' 'gnome-print-sharp' 'gtkhtml-sharp' 'gtksourceview2-sharp' 'rsvg2-sharp' 'vte-sharp' 'wnck-sharp')
pkgver=2.26.0
pkgrel=6
arch=('i686' 'x86_64')
license=(LGPL)
url="http://gtk-sharp.sourceforge.net"
makedepends=('gnome-sharp>=2.24.1' 'vte>=0.23.5' 'librsvg>=2.26.0' 'gnome-panel-bonobo>=2.29.91' 'libgnomeprintui>=2.18.4' 'libwnck>=2.29.91' 'gtkhtml>=3.29.91' 'gtksourceview2>=2.9.2' 'monodoc')
options=('!libtool')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/2.26/${pkgname}-${pkgver}.tar.bz2
	gnome-desktop-sharp-lib-target.patch)
md5sums=('4bc990900bb318b2ba0b0e7998bb47d1'
         '980cd3adf5e745f4caee0a172a51dcc3')

build() {
   # get rid of that .wapi errors; thanks to brice
    export MONO_SHARED_DIR="${srcdir}/weird"
    mkdir -p "${MONO_SHARED_DIR}"

    cd "${srcdir}/${pkgname}-${pkgver}"
    patch -Np1 -i "${srcdir}/gnome-desktop-sharp-lib-target.patch"
    ./configure --prefix=/usr --sysconfdir=/etc
    make
}

package_gnome-desktop-sharp() {
    pkgdesc="GNOME desktop bindings for C#"
    depends=('libgnome-desktop-sharp' 'gnome-panel-sharp' 'gnome-print-sharp' 'gtkhtml-sharp' 'gtksourceview2-sharp' 'rsvg2-sharp' 'vte-sharp' 'wnck-sharp')
}

package_libgnome-desktop-sharp() {
    pkgdesc="Mono bindings for libgnome-desktop"
    depends=('gtk-sharp-2>=2.12.2' 'gnome-desktop>=2.25.0')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gnomedesktop install DESTDIR="${pkgdir}"
}

package_gnome-panel-sharp() {
    pkgdesc="Mono bindings for libpanelapplet"
    depends=('libgnome-sharp>=2.24.1' 'gnome-panel-bonobo>=2.29.91')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gnomepanel install DESTDIR="${pkgdir}"
}

package_gnome-print-sharp() {
    pkgdesc="Mono bindings for libgnomeprint and libgnomeprintui"
    depends=('art-sharp>=2.24.1' 'libgnomeprintui>=2.18.4')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gnomeprint install DESTDIR="${pkgdir}"
}

package_gtkhtml-sharp() {
    pkgdesc="Mono bindings for gtkhtml"
    depends=('gtk-sharp-2>=2.12.2' 'gtkhtml>=3.29.91')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gtkhtml install DESTDIR="${pkgdir}"
}

package_gtksourceview2-sharp() {
    pkgdesc="Mono bindings for gtksourceview2"
    depends=('gtk-sharp-2>=2.12.2' 'gtksourceview2>=2.9.2')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gtksourceview install DESTDIR="${pkgdir}"
}

package_rsvg2-sharp() {
    pkgdesc="Mono bindings for librsvg"
    depends=('gtk-sharp-2>=2.12.2' 'librsvg>=2.26.0')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C rsvg install DESTDIR="${pkgdir}"
}

package_vte-sharp() {
    pkgdesc="Mono bindings for libvte"
    depends=('gtk-sharp-2>=2.12.2' 'vte>=0.23.5')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C vte install DESTDIR="${pkgdir}"
}

package_wnck-sharp() {
    pkgdesc="Mono bindings for libwnck"
    depends=('gtk-sharp-2>=2.12.2' 'libwnck>=2.29.91')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C wnck install DESTDIR="${pkgdir}"
}