# $Id: PKGBUILD 30955 2009-03-22 19:41:36Z jgc $
# Maintainer: tobias <tobias@archlinux.org>

pkgbase=gnome-sharp
pkgname=('gnome-sharp' 'art-sharp' 'gconf-sharp' 'gconf-sharp-peditors' 'libgnome-sharp' 'gnome-vfs-sharp')
pkgver=2.24.2
pkgrel=1
arch=(i686 x86_64)
license=(LGPL)
url="http://gtk-sharp.sourceforge.net"
makedepends=('gtk-sharp-2>=2.12.8' 'libgnomeui>=2.24.1' 'monodoc')
options=('!libtool')
source=(http://ftp.gnome.org/pub/gnome/sources/gnome-sharp/2.24/${pkgname}-${pkgver}.tar.bz2)
md5sums=('3b38f53960c736d4afb8f04204efe98b')

build() {
   # get rid of that .wapi errors; thanks to brice
    export MONO_SHARED_DIR="${srcdir}/weird"
    mkdir -p "${MONO_SHARED_DIR}"

    cd "${srcdir}/${pkgname}-${pkgver}"
    ./configure --prefix=/usr --sysconfdir=/etc
    make
}

package_gnome-sharp() {
    pkgdesc="GNOME bindings for C#"
    depends=('art-sharp' 'gconf-sharp' 'gconf-sharp-peditors' 'libgnome-sharp' 'gnome-vfs-sharp')
}

package_art-sharp() {
    pkgdesc="Mono bindings for libart"
    depends=('gtk-sharp-2>=2.12.8' 'libart-lgpl>=2.3.20')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C art install DESTDIR="${pkgdir}"
}

package_gconf-sharp() {
    pkgdesc="Mono bindings for GConf"
    depends=('gtk-sharp-2>=2.12.8' 'gconf')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gconf/GConf install DESTDIR="${pkgdir}"
    make -C gconf/tools install DESTDIR="${pkgdir}"
}

package_gconf-sharp-peditors() {
    pkgdesc="Mono bindings for GConf - Property Editing classes"
    depends=('gconf-sharp' 'libgnome-sharp')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gconf/GConf.PropertyEditors install DESTDIR="${pkgdir}"
}

package_libgnome-sharp() {
    pkgdesc="Mono bindings for libgnome"
    depends=('art-sharp' 'gnome-vfs-sharp' 'libgnomeui>=2.24.1')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gnome install DESTDIR="${pkgdir}"
}

package_gnome-vfs-sharp() {
    pkgdesc="Mono bindings for GNOME-VFS"
    depends=('gtk-sharp-2>=2.12.8' 'gnome-vfs>=2.22.0')

    cd "${srcdir}/${pkgbase}-${pkgver}"
    make -C gnomevfs install DESTDIR="${pkgdir}"
}