# $Id: PKGBUILD 104004 2010-12-25 10:24:12Z allan $
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=curl
pkgver=7.21.4
pkgrel=2
pkgdesc="An URL retrival utility and library"
arch=('i686' 'x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('zlib' 'openssl' 'bash' 'ca-certificates')
makedepends=('perl-libwww')
options=('!libtool')
source=(http://curl.haxx.se/download/${pkgname}-${pkgver}.tar.bz2
        curlbuild.h)
md5sums=('e2dd20c88a7d01c745af9d788545ab2a'
         '751bd433ede935c8fae727377625a8ae')

case $CARCH in
  x86_64) _curlbuild=curlbuild-64.h ;;
  i686) _curlbuild=curlbuild-32.h ;;
esac

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
      --with-random=/dev/urandom \
      --prefix=/usr \
      --mandir=/usr/share/man \
      --disable-dependency-tracking \
      --enable-ipv6 \
      --disable-ldaps \
      --disable-ldap \
      --enable-manual \
      --enable-versioned-symbols \
      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
      --enable-threaded-resolver \
      --without-libidn

  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  make DESTDIR="$pkgdir" install

  # install devel files
  install -Dm644 docs/libcurl/libcurl.m4 "$pkgdir/usr/share/aclocal/libcurl.m4"
  mv "$pkgdir"/usr/include/curl/curlbuild.h "$pkgdir/usr/include/curl/$_curlbuild"
  install -Dm644 "$srcdir"/curlbuild.h "$pkgdir/usr/include/curl/curlbuild.h"

  # license
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}