# $Id: PKGBUILD 107389 2011-01-24 14:13:22Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>

pkgbase=doxygen
pkgname=('doxygen' 'doxygen-docs')
pkgver=1.7.3
pkgrel=2
license=('GPL')
arch=(i686 x86_64)
url="http://www.doxygen.org/"
# qt required to build and run doxywizard, but don't want to drag it in
makedepends=('flex' 'qt' 'texlive-core' 'ghostscript' 'texlive-latexextra')
options=('!makeflags')
source=(ftp://ftp.stack.nl/pub/users/dimitri/${pkgname}-${pkgver}.src.tar.gz)
md5sums=('6cc5ad566dbec5cf843dc600b1162808')
sha1sums=('06e1d84b50beecdfe0f91393b83c29e8a3db1011')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  QTDIR=/usr ./configure --prefix /usr --with-doxywizard
  make
}

package_doxygen() {
  pkgdesc="A documentation system for C++, C, Java, IDL and PHP"
  depends=('gcc-libs')
  optdepends=('graphviz: for caller/callee graph generation'
              'qt: for doxywizard')

  cd "${srcdir}/${pkgname}-${pkgver}"
  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install
}

package_doxygen-docs() {
  pkgdesc="Developer documentation for doxygen"

  cd "${srcdir}/${pkgname}-${pkgver}"
  make INSTALL="${pkgdir}"/usr MAN1DIR=share/man/man1 install_docs
}