# $Id: PKGBUILD 20351 2010-07-05 10:03:47Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Shahar Weiss <sweiss4@gmx.net>

pkgbase=torcs
pkgname=('torcs' 'torcs-data')
pkgver=1.3.2_test1
pkgrel=1
pkgdesc="A 3D racing cars simulator using OpenGL"
url="http://torcs.sourceforge.net"
license=("GPL")
arch=('i686' 'x86_64')
depends=('freeglut' 'libpng' 'freealut' 'libxi' 'libxmu' 'libxrandr')
makedepends=('plib')
options=('!makeflags')
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-${pkgver/_/-}.tar.bz2 \
	torcs.desktop \
	torcs.sh \
	torcs-gcc.patch)
md5sums=('978b908a42ff6bc235a791bba3fa66b9'
         '328e419e9f985c3e7b69924fe299330d'
         '3f2a94755b86d4c2d1eda420d9b5606b'
         '5ae7e903df37300d3b8744328c756bff')

build() {
  cd $srcdir/$pkgname-${pkgver/_/-}

  unset LDFLAGS
  ./configure --prefix=/opt/torcs  --disable-dependency-tracking \
      --x-includes=/usr/include --x-libraries=/usr/lib --enable-xrandr
  make || return 1
}

package_torcs() {
  depends=('freeglut' 'libpng' 'freealut' 'libxi' 'libxmu' 'libxrandr' 'torcs-data')
  cd $srcdir/$pkgname-${pkgver/_/-}
  make DESTDIR=$pkgdir install || return 1

  install -D -m644 Ticon.png $pkgdir/usr/share/pixmaps/torcs.png && \
  install -D -m644 ../torcs.desktop $pkgdir/usr/share/applications/torcs.desktop && \
  install -D -m755 ../torcs.sh $pkgdir/etc/profile.d/torcs.sh || return 1

  find $pkgdir -type d -exec chmod 755 {} \;
}

package_torcs-data() {
  arch=('any')
  depends=()
  cd $srcdir/torcs-${pkgver/_/-}
  make DESTDIR=$pkgdir datainstall || return 1
  find $pkgdir -type d -exec chmod 755 {} \;
}