# $Id: PKGBUILD 74603 2010-03-31 18:55:53Z giovanni $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Committer: Judd Vinet <jvinet@zeroflux.org>

pkgname=(nasm nasm-docs)
pkgver=2.08.01
pkgrel=4
pkgdesc="80x86 assembler designed for portability and modularity"
url="http://www.nasm.us"
license=(BSD)
arch=('i686' 'x86_64')
depends=('glibc')
makedepends=(groff ghostscript)
source=(http://www.nasm.us/pub/nasm/releasebuilds/${pkgver}/${pkgname}-${pkgver}.tar.bz2)
md5sums=('1e3ebc1289c2be5963571c0937b7a211')
sha256sums=('049b9a1381c0c775a07490f272a57c1802627cbfd6b2d675770b72078bdd8bc6')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr || return 1
  make everything || return 1
}

package_nasm() {
  install=nasm.install

  cd "${srcdir}/${pkgname}-${pkgver}"
  make INSTALLROOT="${pkgdir}" install || return 1
  make INSTALLROOT="${pkgdir}" install_rdf || return 1

  # install info docs manually for now, since the Makefile won't install
  # them alone
  mkdir -p "${pkgdir}/usr/share/info"
  install -m 644 doc/info/* "${pkgdir}/usr/share/info"

  # install license manually
  mkdir -p "${pkgdir}/usr/share/licenses/nasm"
  install -m 644 LICENSE "${pkgdir}/usr/share/licenses/nasm"
}

package_nasm-docs() {
  depends=()

  cd "${srcdir}/${pkgname}-${pkgver}"
  make INSTALLROOT="${pkgdir}" install_doc || return 1

  # remove info docs
  rm -Rv "${pkgdir}/usr/share/info"

  # move documentation (the above creates $pkgdir/usr/share)
  mv "${pkgdir}/usr/doc" "${pkgdir}/usr/share/doc" || return 1
}