# $Id: PKGBUILD 78514 2010-04-24 17:06:00Z ibiru $
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sebastien Piccand <sebcactus gmail com>
# Contributor: Matt Monaco <net##verizon##dgbaley27>

pkgbase=('handbrake')
pkgname=('handbrake' 'handbrake-cli')
pkgver=0.9.4
pkgrel=3
arch=('i686' 'x86_64')
license=('GPL')
url="http://handbrake.fr/"
makedepends=('intltool' 'python>=2.6' 'yasm')
source=(http://saintdevelopment.com/mirror/${pkgname}/HandBrake-${pkgver}.tar.bz2
	gtk2.20_fixes.patch)
md5sums=('69f88b2e602550615da75947f914d7e6'
         'e0296baaed129dceaf0d29c8284dc9fe')

build() {
  cd ${srcdir}/HandBrake-${pkgver}

  #this patch is cherry picked from svn. remove it when updating to a new version
  patch -Np0 -i ${srcdir}/gtk2.20_fixes.patch || return 1
  
  ./configure --prefix=/usr --force || return 1
  
  cd build
  make || return 1

}

package_handbrake() {
  pkgdesc="Multiplatform, multithreaded DVD to MPEG-4/H264/Theora converter"
  depends=('bzip2' 'hal' 'libnotify' 'libwebkit' 'hicolor-icon-theme')
  install=${pkgname}.install
  conflicts=('handbrake-cli')
  provides=("handbrake-cli=${pkgver}")

  cd ${srcdir}/HandBrake-${pkgver}/build
  make DESTDIR="${pkgdir}" install || return 1

}

package_handbrake-cli() {
  pkgdesc="Multiplatform, multithreaded DVD to MPEG-4/H264/Theora converter (CLI only version)"
  depends=('bzip2')
  conflicts=('handbrake')

  cd ${srcdir}/HandBrake-${pkgver}/build
  install -D HandBrakeCLI ${pkgdir}/usr/bin/HandBrakeCLI
}