# $Id$
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>
# Contributor: Evangelos Foutras <foutrelis@gmail.com>

pkgname=bash-completion
pkgver=20091009
pkgrel=1
pkgdesc="Programmable completion for the bash shell"
arch=(any)
url="http://bash-completion.alioth.debian.org/"
license=('GPL')
depends=('bash')
source=(ftp://ftp.archlinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz)

# To regenerate: source PKGBUILD && mksrc
mksrc() {
  local giturl="http://git.debian.org/git/bash-completion/bash-completion.git"
  local name="$pkgname-$(date +%Y%m%d)"
  if [ -d $pkgname ] ; then
    cd $pkgname && git pull origin
    echo "The local files are updated."
  else
    git clone $giturl
    cd $pkgname
  fi
  local commit="$(git log -n1 --pretty=oneline | cut -d' ' -f1)"
  git archive --format=tar --prefix="$name/" HEAD | gzip >../"$name.tar.gz"
  echo "created $name.tar.gz for commit $commit"
  cd ..
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # fixes for archlinux
  sed -i 's#/sbin/lsmod#/bin/lsmod#' bash_completion || return 1

  ./autogen.sh || return 1
  ./configure --prefix=/usr --sysconfdir=/etc || return 1
  make || return 1
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: