# $Id: PKGBUILD 67033 2010-02-02 13:07:05Z giovanni $
# Contributer: Jason Chu <jason@archlinux.org>
# Maintainer: Juergen Hoetzel <jason@archlinux.org>
# Contributor: Bogdan Szczurek <thebodzio@gmail.com>

pkgname=kismet
_realver='2010-07-R1'
pkgver="${_realver//-/_}"
pkgrel=1
pkgdesc="802.11 layer2 wireless network detector, sniffer, and intrusion detection system"
arch=('i686' 'x86_64')
url="http://www.kismetwireless.net/"
license=('GPL')
depends=('libcap' 'libnl' 'pcre' 'ncurses' 'libpcap>=1.0.0' 'bluez' 'openssl')
optdepends=('gpsd: log coordinates of detected networks'
            'wireshark: provide OUI files used to determine device manufacturer'
            'wireshark: mergecap, to merge multiple capture files'
            'sox: provide the default kismet sound playback binary'
            'festival: text-to-speech support'
            'flite:  alternative/lightweight text-to-speech support')
backup=('etc/kismet.conf' 'etc/kismet_drone.conf')
options=()
install='kismet.install'
source=("http://www.kismetwireless.net/code/kismet-$_realver.tar.gz")
md5sums=('85e59186eb529889118b5635f35cf57d')

build() {
   cd "$srcdir/kismet-$_realver"

   ./configure --prefix=/usr \
               --sysconfdir=/etc \
               --localstatedir=/var || return 1

   make dep || return 1
   make || return 1
   make DESTDIR="$pkgdir" install || return 1

   # Include plugins bundled with kismet
   make plugins || return 1
   make plugins-install DESTDIR="$pkgdir" || return 1

   # the README is very comprehensive, a good idea to include it
   install -D -m 644 "$srcdir/kismet-$_realver/README" "$pkgdir/usr/share/kismet/README"

   # Our own suid-install, first half (see kismet.install)
   install -o "root" -g "root" -m 4550 kismet_capture "$pkgdir/usr/bin/"
}