# $Id: PKGBUILD 67033 2010-02-02 13:07:05Z giovanni $
# Contributer: Jason Chu <jason@archlinux.org>
# Maintainer: Juergen Hoetzel <jason@archlinux.org>

pkgname=kismet
pkgver=2010_01_R1
_realver="${pkgver//_/-}"
pkgrel=2
pkgdesc="802.11 layer2 wireless network detector, sniffer, and intrusion detection system"
arch=('i686' 'x86_64')
url="http://www.kismetwireless.net/"
license=('GPL')
depends=('libcap' 'libnl' 'pcre' 'ncurses' 'libpcap>=1.0.0' 'bluez' 'openssl') # already in core: ('linux-api-headers' 'glibc')
makedepends=() # already in core: ('grep' 'gcc-libs')
optdepends=('gpsd: log coordinates of detected networks'
            'wireshark: provide OUI files used to determine device manufacturer'
            'wireshark: mergecap, to merge multiple capture files'
            'sox: provide the default kismet sound playback binary'
            'festival: text-to-speech support'
            'flite:  alternative/lightweight text-to-speech support'
            'mac80211 driver: full rfmon support')
backup=('etc/kismet.conf' 'etc/kismet_drone.conf')
options=()
install='kismet.install'
source=(http://www.kismetwireless.net/code/kismet-2010-01-R1.tar.gz)
md5sums=('a6d6edcf65d5bb2cb5de6472bcc16f19')

build() {
   cd "$srcdir/kismet-$_realver"

   ./configure --prefix=/usr \
               --sysconfdir=/etc \
               --localstatedir=/var || return 1

   make dep || return 1
   make || return 1
   make DESTDIR="$pkgdir" install || return 1

   # Include plugins bundled with kismet
   make plugins || return 1
   make plugins-install DESTDIR="$pkgdir" || return 1

   # the README is very comprehensive, a good idea to include it
   install -D -m 644 "$srcdir/kismet-$_realver/README" "$pkgdir/usr/share/kismet/README"

   # Our own suid-install, first half (see kismet.install)
   install -o "root" -g "root" -m 4550 kismet_capture "$pkgdir/usr/bin/"
}

################################################################################
# References to Newcore changes
################################################################################

# Files that are no longer shipped and so should not be backed up
#backup=('etc/ap_manuf' 'etc/client_manuf' 'etc/kismet_ui.conf')

# No longer needed; gpsmap is deprecated and being replaced with a tile-based
# mapper, as of yet incomplete
#optdepends=('perl-libwww: fetch maps for gpsmap')

# Configuration has completely changed, no longer containing
# references to either prism2 or wlanng
#sed -i 's/prism2/wlanng/g' conf/kismet.conf || return 1

# Ownership of man pages now defaults to "root" if the group "man" does not exist
#chown root:root "$pkgdir"/usr/share/man/man{1,5}/*

# The *.conf unexpanded ${prefix} problems no longer exist
#sed -i 's%\${prefix}%/usr%' "$pkgdir"/etc/*.conf || return 1

# Dependencies no longer needed
#depends=('gmp' 'imagemagick' 'dbus' 'libjpeg>=7')

# Options no longer needed
#options=('!makeflags')