# $Id: PKGBUILD 45614 2009-07-13 18:07:29Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Loui Chang <louipc dot ist at gmail company>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=mtools
pkgver=4.0.10
pkgrel=4
pkgdesc="A collection of utilities to access MS-DOS disks"
url="http://mtools.linux.lu/"
source=(http://ftp.gnu.org/gnu/mtools/$pkgname-$pkgver.tar.bz2)
arch=('i686' 'x86_64')
license=('GPL')
makedepends=('texinfo' 'libx11' 'libxau' 'libsm' 'libice')
optdepends=('libx11: required by floppyd'
            'libxau: required by floppyd'
            'libsm:  required by floppyd'
            'libice: required by floppyd')
backup=(etc/mtools.conf)
md5sums=('750c2beba968a5d46dbaae24551a82b9')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  sed -i '/^SAMPLE FILE$/s:^:# :' mtools.conf
  sed -i 's:/usr/local/etc:/etc:g' mtools.5 mtools.texi
  ./configure --prefix=/usr \
	      --sysconfdir=/etc
  make || return 1
  make prefix=${pkgdir}/usr install
  install -Dm644 mtools.conf ${pkgdir}/etc/mtools.conf
  rm -rf ${pkgdir}/usr/share/info/dir
  gzip -9 ${pkgdir}/usr/share/info/mtools.info
}