# $Id: PKGBUILD,v 1.34 2007/10/25 21:01:06 tobias Exp $
# Contributor: John Sowiak <john@archlinux.org>
# Maintainer: tobias <tobias@archlinux.org>

pkgname=blender
pkgver=2.57
pkgrel=1
pkgdesc="A fully integrated 3D graphics creation suite"
arch=('i686' 'x86_64')
license=(GPL)
url="http://blender3d.org"
depends=('libjpeg-turbo' 'libpng' 'openexr' 'sdl' 'python' 'desktop-file-utils' 'fftw' 'lcms' 'libsndfile' 'openjpeg' \
         'gettext' 'ffmpeg' 'ode' 'openal' 'freealut' 'libsamplerate' 'jack-audio-connection-kit' 'opencollada')
makedepends=('glut' 'scons' 'yasm')
install=blender.install
source=(http://download.blender.org/source/${pkgname}-${pkgver}.tar.gz)
md5sums=('e6cb5523323a71c070051e6fe6efe497')

build() {
  rm -rf ${srcdir}/build
  mkdir ${srcdir}/build
  cd ${srcdir}/build

  cmake ../blender \
    -DCMAKE_BUILD_TYPE=release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DWITH_INSTALL_PORTABLE=false \
    -DWITH_BUILDINFO=true \
    -DWITH_BULLET=true \
    -DWITH_CODEC_FFMPEG=true \
    -DWITH_CODEC_SNDFILE=true \
    -DWITH_FFTW3=true \
    -DWITH_GAMEENGINE=true \
    -DWITH_IK_ITASC=true \
    -DWITH_IMAGE_CINEON=false \
    -DWITH_IMAGE_DDS=true \
    -DWITH_IMAGE_HDR=true \
    -DWITH_IMAGE_OPENEXR=true \
    -DWITH_IMAGE_OPENJPEG=true \
    -DWITH_IMAGE_REDCODE=false \
    -DWITH_IMAGE_TIFF=true \
    -DWITH_INTERNATIONAL=true \
    -DWITH_JACK=true \
    -DWITH_LZMA=true \
    -DWITH_LZO=true \
    -DWITH_MOD_BOOLEAN=true \
    -DWITH_MOD_DECIMATE=true \
    -DWITH_MOD_FLUID=true \
    -DWITH_OPENAL=true \
    -DWITH_OPENCOLLADA=true \
    -DWITH_OPENMP=true \
    -DWITH_PLAYER=true \
    -DWITH_PYTHON_INSTALL=false \
    -DWITH_RAYOPTIMIZATION=true \
    -DWITH_SAMPLERATE=true \
    -DWITH_SDL=true \
    -DPYTHON_VERSION=3.2 \
    -DPYTHON_LIBPATH=/usr/lib \
    -DPYTHON_INCLUDE_DIRS=/usr/include/python3.2mu \
    -DPYTHON_LIBRARY=python3.2mu

  make || return 1
  }

package() {
  cd ${srcdir}/build
  make DESTDIR=${pkgdir} install || return 1
  }