# $Id: PKGBUILD 14045 2008-10-02 03:09:29Z kevin $
# Maintainer: kevin <kevin@archlinux.org>
# TU: Kritoke <kritoke@gamebox.net>
# Contributor: Luca Roccia <little_rock@users.sourceforge.net>

pkgname=boost
pkgver=1.37.0
_boostver=${pkgver//./_}
pkgrel=1
pkgdesc="Boost provides free peer-reviewed portable C++ source libraries."
arch=(i686 x86_64)
url="http://www.boost.org/"
depends=('python>=2.5' 'bzip2' 'zlib' 'expat')
source=("http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}_${_boostver}.tar.gz")
license=('custom')
md5sums=('c38b88bb4ebc6d0d9193f432842273d2')

build() {
  # Determine python version.
  local pythonver=$(python --version 2>&1 | sed -r 's/Python ([0-9]+)\.([0-9]+).*/\1.\2/') || return 1

  # Determine where to expect the bjam executable.
  local bindir="bin.linuxx86"
  [ "${CARCH}" = "x86_64" ] && bindir="bin.linuxx86_64"

  # Build bjam if it doesn't exist yet.
  cd "${srcdir}/${pkgname}_${_boostver}/tools/jam/src"
  if [ ! -f "${bindir}/bjam" ]; then
    ./build.sh cc || return 1
  fi

  # Build libraries.
  cd "${srcdir}/${pkgname}_${_boostver}"
  "./tools/jam/src/${bindir}/bjam" \
            release debug-symbols=off threading=single,multi \
			runtime-link=shared link=shared,static \
            "--prefix=${pkgdir}/usr" \
            -sPYTHON_ROOT=/usr \
            "-sPYTHON_VERSION=${pythonver}" \
            -sEXPAT_INCLUDE=/usr \
            -sEXPAT_LIBPATH=/usr \
            toolset=gcc \
            --layout=system \
            --without-mpi \
            install || return 1

  # Copy license.
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 "${srcdir}/${pkgname}_${_boostver}/LICENSE_1_0.txt" \
                "${pkgdir}/usr/share/licenses/${pkgname}/" || return 1
}