# $Id: PKGBUILD 119782 2011-04-15 08:31:34Z jgc $
# Maintainer : tobias <tobias@archlinux.org>
# Contributor: SpepS <dreamspepser at yahoo dot it>

pkgname=gimp
pkgver=2.6.11
pkgrel=6
pkgdesc="GNU Image Manipulation Program"
arch=('i686' 'x86_64')
url="http://www.gimp.org/"
license=('GPL')
depends=('gtk2' 'lcms' 'libxpm' 'libwmf' 'libxmu' 'librsvg' 'libmng' 'dbus-glib'
         'libexif' 'pygtk' 'desktop-file-utils' 'gegl')
makedepends=('gutenprint' 'intltool' 'libwebkit' 'poppler-glib'
             'pkg-config' 'alsa-lib' 'iso-codes')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support'
            'libwebkit: for the help browser'
            'poppler-glib: for pdf support'
            'alsa-lib: for MIDI event controller module')
options=('!libtool' '!makeflags')
conflicts=('gimp-devel')
install="gimp.install"
source=("ftp://ftp.gimp.org/pub/gimp/v${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2" 
        "linux.gpl"
        "uri-backend-wget.patch")
md5sums=('bb2939fe13e54fc7255cef5d097bb5dd'
         'bb27bc214261d36484093e857f015f38'
         'e733a412be6172cb081a4c6aebb9da44')
sha1sums=('2f9d596e727bdbf304fa78257c1731d9faf3934c'
          '110ce9798173b19a662d086ed7b882b4729f06cf'
          '5a005723c27e8a55112cb94bb2d9977849886292')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # python2 fix
  export PYTHON="python2"

  # FS#12321 fix and enable file-uri wget backend
  patch -p1 -i ../uri-backend-wget.patch

  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --enable-mp \
              --enable-gimp-console \
              --enable-gimp-remote \
              --enable-python \
              --with-gif-compression=lzw \
              --without-aa \
              --without-hal \
              --without-gnomevfs \
              --without-gvfs \
              --without-libcurl
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install-strip
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/lib/gimp/2.0/plug-ins/*.py
  install -D -m644 "${srcdir}/linux.gpl" "${pkgdir}/usr/share/gimp/2.0/palettes/Linux.gpl"

  rm "${pkgdir}/usr/share/man/man1/gimp-console.1"
  ln -s gimp-console-${pkgver%.*}.1.gz "${pkgdir}/usr/share/man/man1/gimp-console.1.gz"
  ln -s gimptool-2.0 "${pkgdir}/usr/bin/gimptool"
  ln -sf gimptool-2.0.1.gz "${pkgdir}/usr/share/man/man1/gimptool.1.gz"
}