# $Id: PKGBUILD,v 1.18 2008/03/17 04:47:13 Snowman Exp $
# Maintainer: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>

pkgname=pulseaudio
pkgver=0.9.9
pkgrel=2.1
pkgdesc="A networked sound server"
arch=('i686' 'x86_64')
url="http://pulseaudio.org/"
license=('GPL' 'LGPL')
depends=('hal' 'libasyncns' 'libcap' 'liboil' 'libsamplerate' 'libtool')
makedepends=('autoconf' 'automake' 'avahi' 'gconf' 'jack-audio-connection-kit' 'libatomic_ops' 'libtool' 'lirc-utils'
             'pkgconfig' 'tcp_wrappers' 'bluez-libs')
provides=('polypaudio')
conflicts=('polypaudio')
replaces=('polypaudio')
options=('emptydirs' '!libtool' '!makeflags')
backup=('etc/pulse/client.conf' 'etc/pulse/daemon.conf' 'etc/pulse/default.pa')
install=pulseaudio.install
source=(http://0pointer.de/lennart/projects/pulseaudio/${pkgname}-${pkgver}.tar.gz
        pulseaudio.conf
        pulseaudio.rc
        libtool2.patch.gz)  # From http://pulseaudio.org/ticket/168
md5sums=('8fa6f7a9611bb194d94311764022b197'
         'd4a7d4ad51b406588ba7ac7931c5dd88'
         '0ca49a8494711beaab7256d7720131b1'
         'ed0b27a26ca8a0810aae01da45e86c39')

build() {
  cd ${startdir}/src/${pkgname}-${pkgver}

  patch -Np0 -i ../libtool2.patch || return 1
  autoreconf -fi || return 1
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-lynx \
              --disable-ltdl-install || return 1
  make || return 1
  make DESTDIR=${startdir}/pkg install || return 1

  install -Dm755 ${startdir}/src/pulseaudio.rc ${startdir}/pkg/etc/rc.d/pulseaudio || return 1
  install -Dm644 ${startdir}/src/pulseaudio.conf ${startdir}/pkg/etc/conf.d/pulseaudio || return 1
  install -d ${startdir}/pkg/var/run/pulse || return 1
}

# vim:set ts=2 sw=2 et: