# $Id: PKGBUILD,v 1.11 2007/08/17 09:14:28 alexander Exp $
# Maintainer: Alexander Baldeck <alexander@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=xorg-xdm
pkgver=1.1.6
pkgrel=2
pkgdesc="X Display Manager"
arch=(i686 x86_64)
url="http://xorg.freedesktop.org/"
depends=('libxaw' 'libxinerama' 'xorg-server-utils' 'libxft')
makedepends=('pkgconfig')
backup=(etc/X11/xdm/Xaccess etc/X11/xdm/Xresources etc/X11/xdm/Xservers etc/X11/xdm/xdm-config etc/pam.d/xdm)
options=('!libtool')
source=(${url}/releases/individual/app/xdm-${pkgver}.tar.bz2
	xdm.pam
	Xresources.patch)

build() {
  cd ${startdir}/src/xdm-${pkgver}
  patch -Np1 -i ${startdir}/src/Xresources.patch
  ./configure --prefix=/usr \
              --disable-static \
	      --disable-xprint \
	      --with-xdmconfigdir=/etc/X11/xdm \
	      --with-xdmscriptdir=/etc/X11/xdm \
	      --with-pixmapdir=/usr/share/xdm/pixmaps
  make || return 1
  make DESTDIR=${startdir}/pkg install || return 1
  mkdir -p ${startdir}/pkg/etc/pam.d
  install -m644 ${startdir}/src/xdm.pam ${startdir}/pkg/etc/pam.d/xdm

  #Get rid of /usr/X11R6
  cd ${startdir}/pkg/etc/X11/xdm
  sed -i -e 's/\/X11R6//g' *
}

md5sums=('c89f8bc74fda4d19e5f374f59c88810f'
         '419d6289ba6f851135f5c70c0e3cbec4'
	 '7b112ffdd9efccfdf18c895af9869bda')