# $Id: PKGBUILD,v 1.49 2006/11/24 23:23:38 jgc Exp $
# Maintainer: dale <dale@archlinux.org>
# Modified by: Mildred <silkensedai@online.fr> fix bug GNOME#384026

pkgname=epiphany
pkgver=2.16.2
pkgrel=1.mildred6
install=epiphany.install
pkgdesc="A GNOME2 web browser based on the mozilla rendering engine."
arch=(i686 x86_64)
depends=('xulrunner>=1.8.1' 'gnome-desktop>=2.16.1' 'iso-codes')
makedepends=('intltool' 'gnome-doc-utils' 'gnome-python>=2.16.0' 'pkgconfig' 'networkmanager')
options=('nolibtool')
groups=(gnome)
url="http://www.gnome.org/projects/epiphany/"
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/2.16/${pkgname}-${pkgver}.tar.bz2)
md5sums=('6d4ca4c3c1fb52b432ad3f5006866b6b')

build() {
  [ -z "${GNOMEDIR}" ] && . /etc/profile.d/gnome.sh
  [ -z "${MOZ_PLUGIN_PATH}" ] && . /etc/profile.d/mozilla-common.sh

  cd ${startdir}/src/${pkgname}-${pkgver}
  sed -i -e 's|pydefsdir =.*|pydefsdir = /usr/share/pygtk/2.0/defs|' \
      src/Makefile.* || return 1
  [ -e configured-${pkgrel} ] || \
  ./configure --prefix=/opt/gnome \
  	--disable-python \
  	--disable-spell-checker \
  	--enable-certificate-manager \
  	--enable-dbus \
  	--disable-scrollkeeper \
  	--with-mozilla=xulrunner \
  	--enable-network-manager \
  || return 1
  touch configured-${pkgrel}
  make LDFLAGS+="-R /opt/mozilla/lib/xulrunner" || return 1
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${startdir}/pkg install || return 1

  mkdir -p ${startdir}/pkg/opt/gnome/share/gconf/schemas
  gconf-merge-schema ${startdir}/pkg/opt/gnome/share/gconf/schemas/${pkgname}.schemas ${startdir}/pkg/opt/gnome/etc/gconf/schemas/*.schemas
  rm -f ${startdir}/pkg/opt/gnome/etc/gconf/schemas/*.schemas
}