# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Andres Perera <andres87p gmail>
# Contributor: Matthew Bauer <mjbauer95@gmail.com>
# Contributor: Christian Himpel <chressie at gmail dot com>

pkgname=go
pkgver=2010_08_11
_pkgver=2010-08-11
pkgrel=3
pkgdesc='Google Go compiler and tools (release version)'
arch=(i686 x86_64)
url=http://golang.org/
license=(custom)
depends=(perl)
makedepends=(mercurial)
options=(!strip !makeflags)
install=$pkgname.install
source=($pkgname.sh)
md5sums=('67c472bfcfdb760d1d1f0a87cfe3661f')

build() {
  hgroot=https://go.googlecode.com/hg/
  hgrepo=release

  cd $srcdir

  msg "Connecting to Mercurial server..."
  if [ -d $hgrepo ]; then
    cd $hgrepo
    hg pull -u
    msg2 "The local files have been updated"
  else
    hg clone $hgroot $hgrepo
    msg2 "Mercurial checkout done"
  fi

  ARCH=$(uname -m)
  [ "$ARCH" == "i686" ]   && GOARCH=386
  [ "$ARCH" == "arm" ]    && GOARCH=arm
  [ "$ARCH" == "x86_64" ] && GOARCH=amd64
  export GOARCH

  export GOROOT=$srcdir/$hgrepo
  export GOOS=linux
  export GOBIN=$GOROOT/bin
  export PATH=$GOBIN:$PATH

  mkdir -p $GOROOT/bin
  cd $GOROOT/src
  hg update release.$_pkgver

  cd $GOROOT/src
  ./all.bash

  cd $GOROOT
  install -Dm644 LICENSE $pkgdir/usr/share/licenses/go/LICENSE
  install -Dm644 misc/bash/go $pkgdir/etc/bash_completion.d/go
  install -Dm644 misc/emacs/go-mode-load.el $pkgdir/usr/share/emacs/site-lisp/go-mode-load.el
  install -Dm644 misc/emacs/go-mode.el $pkgdir/usr/share/emacs/site-lisp/go-mode.el
  install -Dm644 misc/vim/ftdetect/gofiletype.vim $pkgdir/usr/share/vim/vimfiles/ftdetect/gofiletype.vim
  install -Dm644 misc/vim/syntax/go.vim $pkgdir/usr/share/vim/vimfiles/syntax/go.vim

  mkdir -p $pkgdir/{etc/profile.d,usr/{share/go,lib/go/lib,lib/go/src}}

  cp -r bin $pkgdir/usr
  cp -r doc misc -t $pkgdir/usr/share/go
  cp -r lib/godoc $pkgdir/usr/lib/go/lib
  cp -r pkg $pkgdir/usr/lib/go

  ln -s ../../share/go/doc $pkgdir/usr/lib/go/doc

  install -Dm644 src/Make.{$GOARCH,common,cmd,pkg,conf} $pkgdir/usr/lib/go/src

  # Headers for C modules
  install -Dm644 src/pkg/runtime/runtime.h $pkgdir/usr/lib/go/src/pkg/runtime/runtime.h
  install -Dm644 src/pkg/runtime/cgocall.h $pkgdir/usr/lib/go/src/pkg/runtime/cgocall.h

  install  $srcdir/go.sh $pkgdir/etc/profile.d/

  echo export GOARCH=$GOARCH >> $pkgdir/etc/profile.d/go.sh
}