# $Id: PKGBUILD 54816 2009-10-11 19:40:09Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gdm
pkgver=2.28.0
pkgrel=2
pkgdesc="Gnome Display Manager (a reimplementation of xdm)"
arch=(i686 x86_64)
license=('GPL')
url="http://www.gnome.org"
backup=('etc/pam.d/gdm' 'etc/pam.d/gdm-autologin' 'etc/gdm/custom.conf')
groups=('gnome-extra')
options=('!libtool')
depends=('libcanberra>=0.14' 'gnome-panel>=2.28.0' 'libxklavier>=4.0' 'tcp_wrappers' 'gnome-session>=2.28.0' 'devicekit-power>=010')
makedepends=('intltool' 'gnome-doc-utils>=0.18.0' 'xorg-server')
conflicts=('fast-user-switch-applet')
replaces=('fast-user-switch-applet')
install=gdm.install
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/2.28/${pkgname}-${pkgver}.tar.bz2
        04_fix_external_program_directories.patch
        gdm-2.28.0-use-devicekit-power.patch
        gdm.pam
        gdm-autologin.pam
        gdm
        01_default_keyboard_layout_hal.patch)
md5sums=('7724929a6b75ba269fd519d4a4995bbb'
         '0e883f1e99512af98afa219d1670f1bd'
         '804c6ef3879940f6a5702fc6e9ca6c2c'
         '2e52f326dccc833e9c135f8df8297b12'
         '157f32e089a7aab50732dc122e592b35'
         '87096c2424824d67fd3d549fea4d6f22'
         '433340ca73699b7b4c3da28e7e631b01')


build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i "${srcdir}/04_fix_external_program_directories.patch" || return 1
  patch -Np1 -i "${srcdir}/01_default_keyboard_layout_hal.patch" || return 1
  patch -Np1 -i "${srcdir}/gdm-2.28.0-use-devicekit-power.patch" || return 1
  libtoolize --force || return 1
  aclocal || return 1
  autoconf || return 1
  automake || return 1
  ./configure --prefix=/usr --sysconfdir=/etc \
      --libexecdir=/usr/lib/gdm --localstatedir=/var --disable-static \
      --disable-scrollkeeper || return 1
  make || return 1
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install || return 1
  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain gdm ${pkgdir}/etc/gconf/schemas/*.schemas || return 1
  rm -r "${pkgdir}/etc/gconf/schemas/"

  install -m644 "${srcdir}/gdm.pam" "${pkgdir}/etc/pam.d/gdm" || return 1
  install -m644 "${srcdir}/gdm-autologin.pam" "${pkgdir}/etc/pam.d/gdm-autologin" || return 1

  install -m755 -d "${pkgdir}/etc/rc.d"
  install -m755 "${srcdir}/gdm" "${pkgdir}/etc/rc.d/" || return 1

  rmdir "${pkgdir}/var/gdm"
}