# $Id: PKGBUILD 56188 2009-10-20 08:00:06Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=file-roller
pkgver=2.28.1
pkgrel=1
pkgdesc="Archive manipulator for GNOME2"
arch=(i686 x86_64)
license=('GPL')
depends=('desktop-file-utils' 'gconf>=2.28.0')
makedepends=('intltool' 'gnome-doc-utils>=0.18.0' 'pkgconfig' 'nautilus>=2.28.0')
optdepends=('nautilus: nautilus shell extension'
			'tar: tar archiving utility '
			'gzip: GNU compression utilities'
			'bzip2: high-quality block-sorting file compressor - utilities '
			'arj: archiver for .arj files '
			'unrar: Unarchiver for .rar files'
			'unzip: De-archiver for .zip files '
			'zip: Archiver for .zip files '
			'lha: lzh archiver '
			'lzip: data compressor based on the LZMA algorithm '
			'unace: extract, test and view .ace archives '
			'unalz: De-archiver for .alz files '
			'zoo: manipulate zoo archives '
			'cpio: GNU cpio -- a program to manage archives of files '
			'rzip: compression program for large files '
			'sharutils: shar, unshar, uuencode, uudecode')
groups=('gnome-extra')
options=('!libtool' '!emptydirs')
install=file-roller.install
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/2.28/${pkgname}-${pkgver}.tar.bz2)
sha256sums=('ce1b18d0ec5e383ef64def91b67c96cebd8adfb99ac3b4bcac0ae40c90a12250')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --libexecdir=/usr/lib/file-roller \
      --localstatedir=/var --disable-static \
      --disable-scrollkeeper || return 1
  make || return 1
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install || return 1

  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain file-roller ${pkgdir}/etc/gconf/schemas/*.schemas || return 1
  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
}